build.gradle

plugins {
    id 'fml-loom' version '0.1'
    id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

base {
    // The name of the generated JAR file.
    // "[xxxx]" + project.archives_base_name to add an alias
    archivesName = project.archives_base_name
}

//base {
//    archivesName = "[中文名]" + project.archives_base_name
//}

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.
    maven {
        name = "Spongepowered"
        url = "https://repo.spongepowered.org/repository/maven-public/"
    }// Dependency library(FastUtil, Gson, etc) download source
    maven {
        name = "ModdedMITE"
        url = "https://maven.limingzxc.top/repository/maven-public/"
    }// Mods & Loaders download source
}

configurations {
    fml
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    implementation("it.unimi.dsi:fastutil:8.5.12")
    implementation("com.google.code.gson:gson:2.11.0")

    fml "com.github.MinecraftIsTooEasy:FishModLoader:3.4.2"
    implementation "com.github.MinecraftIsTooEasy:FishModLoader:3.4.2"

    // The most basic dependency library mod, with a status similar to Fabric API
    implementation "com.github.MinecraftIsTooEasy:RustedIronCore:1.5.0"

    // To add strong dependencies, use "implementation" like above
    // To compile mod integrations(e.g. ModMenu), use "compileOnly"
    // To add mods for running client, use "localRuntime"
}

def fmlResolvedFile = configurations.fml.files.iterator().next()

loom {
    accessWidenerPath = file("src/main/resources/modid.accesswidener")
    mergedMinecraftJar()
    mods {
        "modid" {
            sourceSet sourceSets.main
//            sourceSet sourceSets.client
//            sourceSet sourceSets.server
//            For modules in the ’src‘ directory, only the main module is required by default
        }
    }
}

loom.setFML(fmlResolvedFile)
dependencies.add("mappings", loom.fmlMCPMappings())

processResources {
    inputs.property "version", project.version

    filesMatching("fml.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 17
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

jar {
    inputs.property "archivesName", project.base.archivesName

    from("LICENSE") {
        rename { "${it}_${inputs.properties.archivesName}"}
    }
}

tasks.named('runClient', JavaExec).configure { exec ->
    def user = project.hasProperty('username') ? project.username : 'Dev'
    def width = project.hasProperty('screen_width') ? project.screen_width : '854'
    def height = project.hasProperty('screen_height') ? project.screen_height : '480'
    exec.setArgs(['--username', user, '--session', '0', '--width', width, '--height', height])
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}